[fix] Change a lot of things

config/fish/completions/nvm.fish

@@ -1,19 +0,0 @@
-complete --command nvm --exclusive --long version --description "Print version"
-complete --command nvm --exclusive --long help --description "Print help"
-
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments install --description "Download and activate the specified Node version"
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments use --description "Activate a version in the current shell"
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments list --description "List installed versions"
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments list-remote --description "List versions available to install matching optional regex"
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments current --description "Print the currently-active version"
-complete --command nvm --exclusive --condition "__fish_seen_subcommand_from install" --arguments "(
-    test -e $nvm_data && string split ' ' <$nvm_data/.index
-)"
-complete --command nvm --exclusive --condition "__fish_seen_subcommand_from use" --arguments "(_nvm_list | string split ' ')"
-complete --command nvm --exclusive --condition __fish_use_subcommand --arguments uninstall --description "Uninstall a version"
-complete --command nvm --exclusive --condition "__fish_seen_subcommand_from uninstall" --arguments "(
-    _nvm_list | string split ' ' | string replace system ''
-)"
-complete --command nvm --exclusive --condition "__fish_seen_subcommand_from use uninstall" --arguments "(
-    set --query nvm_default_version && echo default
-)"

config/fish/conf.d/nvm.fish

@@ -1,28 +0,0 @@
-function _nvm_install --on-event nvm_install
-    set --query XDG_DATA_HOME || set --local XDG_DATA_HOME ~/.local/share
-    set --universal nvm_data $XDG_DATA_HOME/nvm
-    set --query nvm_mirror || set --universal nvm_mirror https://nodejs.org/dist
-
-    test ! -d $nvm_data && command mkdir -p $nvm_data
-    echo "Downloading the Node distribution index..." 2>/dev/null
-    _nvm_index_update $nvm_mirror $nvm_data/.index
-end
-
-function _nvm_update --on-event nvm_update
-    set --query XDG_DATA_HOME || set --local XDG_DATA_HOME ~/.local/share
-    set --universal nvm_data $XDG_DATA_HOME/nvm
-    set --query nvm_mirror || set --universal nvm_mirror https://nodejs.org/dist
-end
-
-function _nvm_uninstall --on-event nvm_uninstall
-    command rm -rf $nvm_data
-
-    set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
-
-    set --names | string replace --filter --regex -- "^nvm" "set --erase nvm" | source
-    functions --erase (functions --all | string match --entire --regex -- "^_nvm_")
-end
-
-if status is-interactive && set --query nvm_default_version && ! set --query nvm_current_version
-    nvm use $nvm_default_version >/dev/null
-end

config/fish/fish_plugins

@@ -1,2 +1 @@
 jorgebucaran/fisher
-jorgebucaran/nvm.fish

config/fish/fish_variables

@@ -4,8 +4,7 @@ SETUVAR AFTERSHOOT_LOG:desktop_rust_backend\x3dtrace
 SETUVAR BW_SESSION:lW6\x2bALLBSowAJgVMgqI6sSMqku9z/192K\x2bDNX0jF2WlzRGhBtKGlUAqXJgbWKTw/cDKU2MRO5Z/6aQPi6fkA6Q\x3d\x3d
 SETUVAR __fish_initialized:3400
 SETUVAR _fisher_jorgebucaran_2F_fisher_files:/Users/fs0c131y/\x2econfig/fish/functions/fisher\x2efish\x1e/Users/fs0c131y/\x2econfig/fish/completions/fisher\x2efish
-SETUVAR _fisher_jorgebucaran_2F_nvm_2E_fish_files:/Users/fs0c131y/\x2econfig/fish/functions/_nvm_index_update\x2efish\x1e/Users/fs0c131y/\x2econfig/fish/functions/_nvm_list\x2efish\x1e/Users/fs0c131y/\x2econfig/fish/functions/_nvm_version_activate\x2efish\x1e/Users/fs0c131y/\x2econfig/fish/functions/_nvm_version_deactivate\x2efish\x1e/Users/fs0c131y/\x2econfig/fish/functions/nvm\x2efish\x1e/Users/fs0c131y/\x2econfig/fish/conf\x2ed/nvm\x2efish\x1e/Users/fs0c131y/\x2econfig/fish/completions/nvm\x2efish
-SETUVAR _fisher_plugins:jorgebucaran/fisher\x1ejorgebucaran/nvm\x2efish
+SETUVAR _fisher_plugins:jorgebucaran/fisher
 SETUVAR fish_color_autosuggestion:555\x1ebrblack
 SETUVAR fish_color_cancel:\x2dr
 SETUVAR fish_color_command:005fd7
@@ -36,5 +35,3 @@ SETUVAR fish_pager_color_prefix:normal\x1e\x2d\x2dbold\x1e\x2d\x2dunderline
 SETUVAR fish_pager_color_progress:brwhite\x1e\x2d\x2dbackground\x3dcyan
 SETUVAR fish_pager_color_selected_background:\x2dr
 SETUVAR fish_user_paths:/opt/homebrew/bin\x1e/usr/lib/emscripten\x1e/home/fs0c131y/\x2elocal/bin\x1e/home/fs0c131y/\x2ecargo/bin\x1e/opt/homebrew/Cellar/arm\x2dgcc\x2dbin\x408/8\x2d2019\x2dq3\x2dupdate_2/bin\x1e/Users/fs0c131y/\x2ecargo/bin\x1e/Users/fs0c131y/\x2elocal/bin
-SETUVAR nvm_data:/Users/fs0c131y/\x2elocal/share/nvm
-SETUVAR nvm_mirror:https\x3a//nodejs\x2eorg/dist

config/fish/functions/_nvm_index_update.fish

@@ -1,16 +0,0 @@
-function _nvm_index_update --argument-names mirror index
-    if not command curl --location --silent $mirror/index.tab >$index.temp
-        command rm -f $index.temp
-        echo "nvm: Can't update index, host unavailable: \"$mirror\"" >&2
-        return 1
-    end
-
-    command awk -v OFS=\t '
-        /v0.9.12/ { exit } # Unsupported
-        NR > 1 {
-            print $1 (NR == 2  ? " latest" : $10 != "-" ? " lts/" tolower($10) : "")
-        }
-    ' $index.temp >$index
-
-    command rm -f $index.temp
-end

config/fish/functions/_nvm_list.fish

@@ -1,11 +0,0 @@
-function _nvm_list
-    set --local versions $nvm_data/*
-    set --query versions[1] &&
-        string match --entire --regex -- (string match --regex -- "v\d.+" $versions |
-            string escape --style=regex |
-            string join "|"
-        ) <$nvm_data/.index
-
-    command --all node |
-        string match --quiet --invert --regex -- "^$nvm_data" && echo system
-end

config/fish/functions/_nvm_version_activate.fish

@@ -1,4 +0,0 @@
-function _nvm_version_activate --argument-names v
-    set --global --export nvm_current_version $v
-    set --prepend PATH $nvm_data/$v/bin
-end

config/fish/functions/_nvm_version_deactivate.fish

@@ -1,5 +0,0 @@
-function _nvm_version_deactivate --argument-names v
-    test "$nvm_current_version" = "$v" && set --erase nvm_current_version
-    set --local index (contains --index -- $nvm_data/$v/bin $PATH) &&
-        set --erase PATH[$index]
-end

config/fish/functions/nvm.fish

@@ -1,208 +0,0 @@
-function nvm --argument-names cmd v --description "Node version manager"
-    if test -z "$v" && contains -- "$cmd" install use
-        for file in .nvmrc .node-version
-            set file (_nvm_find_up $PWD $file) && read v <$file && break
-        end
-        if test -z "$v"
-            echo "nvm: Invalid version or missing \".nvmrc\" file" >&2
-            return 1
-        end
-    end
-
-    set --local their_version $v
-
-    switch "$cmd"
-        case -v --version
-            echo "nvm, version 2.2.7"
-        case "" -h --help
-            echo "Usage: nvm install <version>    Download and activate the specified Node version"
-            echo "       nvm install              Install version from nearest .nvmrc file"
-            echo "       nvm use <version>        Activate a version in the current shell"
-            echo "       nvm use                  Activate version from nearest .nvmrc file"
-            echo "       nvm list                 List installed versions"
-            echo "       nvm list-remote          List versions available to install"
-            echo "       nvm list-remote <regex>  List versions matching a given regular expression"
-            echo "       nvm current              Print the currently-active version"
-            echo "       nvm uninstall <version>  Uninstall a version"
-            echo "Options:"
-            echo "       -v or --version          Print version"
-            echo "       -h or --help             Print this help message"
-            echo "Variables:"
-            echo "       nvm_arch                 Override architecture, e.g. x64-musl"
-            echo "       nvm_mirror               Set the Node download mirror"
-            echo "       nvm_default_version      Set the default version for new shells"
-        case install
-            _nvm_index_update $nvm_mirror $nvm_data/.index || return
-
-            string match --entire --regex -- (_nvm_version_match $v) <$nvm_data/.index | read v alias
-
-            if ! set --query v[1]
-                echo "nvm: Invalid version number or alias: \"$their_version\"" >&2
-                return 1
-            end
-
-            if test ! -e $nvm_data/$v
-                set --local os (command uname -s | string lower)
-                set --local ext tar.gz
-                set --local arch (command uname -m)
-
-                switch $os
-                    case aix
-                        set arch ppc64
-                    case sunos
-                    case linux
-                    case darwin
-                    case {MSYS_NT,MINGW\*_NT}\*
-                        set os win
-                        set ext zip
-                    case \*
-                        echo "nvm: Unsupported operating system: \"$os\"" >&2
-                        return 1
-                end
-
-                switch $arch
-                    case i\*86
-                        set arch x86
-                    case x86_64
-                        set arch x64
-                    case arm64
-                        string match --regex --quiet "v(?<major>\d+)" $v
-                        if test "$os" = darwin -a $major -lt 16
-                            set arch x64
-                        end
-                    case armv6 armv6l
-                        set arch armv6l
-                    case armv7 armv7l
-                        set arch armv7l
-                    case armv8 armv8l aarch64
-                        set arch arm64
-                end
-
-                set --query nvm_arch && set arch $nvm_arch
-
-                set --local dir "node-$v-$os-$arch"
-                set --local url $nvm_mirror/$v/$dir.$ext
-
-                command mkdir -p $nvm_data/$v
-
-                echo -e "Installing Node \x1b[1m$v\x1b[22m $alias"
-                echo -e "Fetching \x1b[4m$url\x1b[24m\x1b[7m"
-
-                if ! command curl --progress-bar --location $url \
-                        | command tar --extract --gzip --directory $nvm_data/$v 2>/dev/null
-                    command rm -rf $nvm_data/$v
-                    echo -e "\033[F\33[2K\x1b[0mnvm: Invalid mirror or host unavailable: \"$url\"" >&2
-                    return 1
-                end
-
-                echo -en "\033[F\33[2K\x1b[0m"
-
-                if test "$os" = win
-                    command mv $nvm_data/$v/$dir $nvm_data/$v/bin
-                else
-                    command mv $nvm_data/$v/$dir/* $nvm_data/$v
-                    command rm -rf $nvm_data/$v/$dir
-                end
-            end
-
-            if test $v != "$nvm_current_version"
-                set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
-                _nvm_version_activate $v
-            end
-
-            printf "Now using Node %s (npm %s) %s\n" (_nvm_node_info)
-        case use
-            test $v = default && set v $nvm_default_version
-            _nvm_list | string match --entire --regex -- (_nvm_version_match $v) | read v __
-
-            if ! set --query v[1]
-                echo "nvm: Can't use Node \"$their_version\", version must be installed first" >&2
-                return 1
-            end
-
-            if test $v != "$nvm_current_version"
-                set --query nvm_current_version && _nvm_version_deactivate $nvm_current_version
-                test $v != system && _nvm_version_activate $v
-            end
-
-            printf "Now using Node %s (npm %s) %s\n" (_nvm_node_info)
-        case uninstall
-            if test -z "$v"
-                echo "nvm: Not enough arguments for command: \"$cmd\"" >&2
-                return 1
-            end
-
-            test $v = default && test ! -z "$nvm_default_version" && set v $nvm_default_version
-
-            _nvm_list | string match --entire --regex -- (_nvm_version_match $v) | read v __
-
-            if ! set -q v[1]
-                echo "nvm: Node version not installed or invalid: \"$their_version\"" >&2
-                return 1
-            end
-
-            printf "Uninstalling Node %s %s\n" $v (string replace ~ \~ "$nvm_data/$v/bin/node")
-
-            _nvm_version_deactivate $v
-
-            command rm -rf $nvm_data/$v
-        case current
-            _nvm_current
-        case ls list
-            _nvm_list | _nvm_list_format (_nvm_current) $argv[2]
-        case lsr {ls,list}-remote
-            _nvm_index_update $nvm_mirror $nvm_data/.index || return
-            _nvm_list | command awk '
-                FILENAME == "-" && (is_local[$1] = FNR == NR) { next } {
-                    print $0 (is_local[$1] ? " ✓" : "")
-                }
-            ' - $nvm_data/.index | _nvm_list_format (_nvm_current) $argv[2]
-        case \*
-            echo "nvm: Unknown command or option: \"$cmd\" (see nvm -h)" >&2
-            return 1
-    end
-end
-
-function _nvm_find_up --argument-names path file
-    test -e "$path/$file" && echo $path/$file || begin
-        test "$path" != / || return
-        _nvm_find_up (command dirname $path) $file
-    end
-end
-
-function _nvm_version_match --argument-names v
-    string replace --regex -- '^v?(\d+|\d+\.\d+)$' 'v$1.' $v |
-        string replace --filter --regex -- '^v?(\d+)' 'v$1' |
-        string escape --style=regex ||
-        string lower '\b'$v'(?:/\w+)?$'
-end
-
-function _nvm_list_format --argument-names current regex
-    command awk -v current="$current" -v regex="$regex" '
-        $0 ~ regex {
-            aliases[versions[i++] = $1] = $2 " " $3
-            pad = (n = length($1)) > pad ? n : pad
-        }
-        END {
-            if (!i) exit 1
-            while (i--)
-                printf((current == versions[i] ? " ▶ " : "   ") "%"pad"s %s\n",
-                    versions[i], aliases[versions[i]])
-        }
-    '
-end
-
-function _nvm_current
-    command --search --quiet node || return
-    set --query nvm_current_version && echo $nvm_current_version || echo system
-end
-
-function _nvm_node_info
-    set --local npm_path (string replace bin/npm-cli.js "" (realpath (command --search npm)))
-    test -f $npm_path/package.json || set --local npm_version_default (command npm --version)
-    command node --eval "
-        console.log(process.version)
-        console.log('$npm_version_default' ? '$npm_version_default': require('$npm_path/package.json').version)
-        console.log(process.execPath.replace(require('os').homedir(), '~'))
-    "
-end