feat(highlight): migrate to tree-house with Helix queries
Replace tree-sitter-highlight dep with tree-house crate from Helix editor. Add ropey dependency required by tree-house. Reorganize query files from Helix's runtime/queries/ for all 14 supported languages: - bash, c, css, go, html, javascript, json, markdown, nix, python, rust, toml, typescript, yaml - Include ecma, _javascript, _typescript base dirs for JS/TS inheritance - Copy highlights.scm, injections.scm, locals.scm where available This commit establishes the foundation; highlight.rs implementation will follow in subsequent commits.
This commit is contained in:
Timothy DeHerrera
288
queries/ecma/highlights.scm
Normal file
288
queries/ecma/highlights.scm
Normal file
@@ -0,0 +1,288 @@
|
||||
; Tokens
|
||||
;-------
|
||||
|
||||
[
|
||||
";"
|
||||
(optional_chain) ; ?.
|
||||
"."
|
||||
","
|
||||
] @punctuation.delimiter
|
||||
|
||||
[
|
||||
"-"
|
||||
"--"
|
||||
"-="
|
||||
"+"
|
||||
"++"
|
||||
"+="
|
||||
"*"
|
||||
"*="
|
||||
"**"
|
||||
"**="
|
||||
"/"
|
||||
"/="
|
||||
"%"
|
||||
"%="
|
||||
"<"
|
||||
"<="
|
||||
"<<"
|
||||
"<<="
|
||||
"="
|
||||
"=="
|
||||
"==="
|
||||
"!"
|
||||
"!="
|
||||
"!=="
|
||||
"=>"
|
||||
">"
|
||||
">="
|
||||
">>"
|
||||
">>="
|
||||
">>>"
|
||||
">>>="
|
||||
"~"
|
||||
"^"
|
||||
"&"
|
||||
"|"
|
||||
"^="
|
||||
"&="
|
||||
"|="
|
||||
"&&"
|
||||
"||"
|
||||
"??"
|
||||
"&&="
|
||||
"||="
|
||||
"??="
|
||||
"..."
|
||||
] @operator
|
||||
|
||||
(ternary_expression ["?" ":"] @operator)
|
||||
|
||||
[
|
||||
"("
|
||||
")"
|
||||
"["
|
||||
"]"
|
||||
"{"
|
||||
"}"
|
||||
] @punctuation.bracket
|
||||
|
||||
(template_substitution
|
||||
"${" @punctuation.special
|
||||
"}" @punctuation.special) @embedded
|
||||
|
||||
[
|
||||
"async"
|
||||
"debugger"
|
||||
"extends"
|
||||
"from"
|
||||
"get"
|
||||
"new"
|
||||
"set"
|
||||
"target"
|
||||
"with"
|
||||
] @keyword
|
||||
|
||||
[
|
||||
"of"
|
||||
"as"
|
||||
"in"
|
||||
"delete"
|
||||
"typeof"
|
||||
"instanceof"
|
||||
"void"
|
||||
] @keyword.operator
|
||||
|
||||
[
|
||||
"function"
|
||||
] @keyword.function
|
||||
|
||||
[
|
||||
"class"
|
||||
"let"
|
||||
"var"
|
||||
] @keyword.storage.type
|
||||
|
||||
[
|
||||
"const"
|
||||
"static"
|
||||
] @keyword.storage.modifier
|
||||
|
||||
[
|
||||
"default"
|
||||
"yield"
|
||||
"finally"
|
||||
"do"
|
||||
"await"
|
||||
] @keyword.control
|
||||
|
||||
[
|
||||
"if"
|
||||
"else"
|
||||
"switch"
|
||||
"case"
|
||||
] @keyword.control.conditional
|
||||
|
||||
[
|
||||
"while"
|
||||
"for"
|
||||
] @keyword.control.repeat
|
||||
|
||||
[
|
||||
"import"
|
||||
"export"
|
||||
] @keyword.control.import
|
||||
|
||||
[
|
||||
"return"
|
||||
"break"
|
||||
"continue"
|
||||
] @keyword.control.return
|
||||
|
||||
[
|
||||
"throw"
|
||||
"try"
|
||||
"catch"
|
||||
] @keyword.control.exception
|
||||
|
||||
; Variables
|
||||
;----------
|
||||
|
||||
(identifier) @variable
|
||||
|
||||
; Properties
|
||||
;-----------
|
||||
|
||||
(property_identifier) @variable.other.member
|
||||
(private_property_identifier) @variable.other.member.private
|
||||
(shorthand_property_identifier) @variable.other.member
|
||||
(shorthand_property_identifier_pattern) @variable.other.member
|
||||
|
||||
; Function and method definitions
|
||||
;--------------------------------
|
||||
|
||||
(function_expression
|
||||
name: (identifier) @function)
|
||||
(function_declaration
|
||||
name: (identifier) @function)
|
||||
(method_definition
|
||||
name: (property_identifier) @function.method)
|
||||
(method_definition
|
||||
name: (private_property_identifier) @function.method.private)
|
||||
|
||||
(pair
|
||||
key: (property_identifier) @function.method
|
||||
value: [(function_expression) (arrow_function)])
|
||||
(pair
|
||||
key: (private_property_identifier) @function.method.private
|
||||
value: [(function_expression) (arrow_function)])
|
||||
|
||||
(assignment_expression
|
||||
left: (member_expression
|
||||
property: (property_identifier) @function.method)
|
||||
right: [(function_expression) (arrow_function)])
|
||||
(assignment_expression
|
||||
left: (member_expression
|
||||
property: (private_property_identifier) @function.method.private)
|
||||
right: [(function_expression) (arrow_function)])
|
||||
|
||||
(variable_declarator
|
||||
name: (identifier) @function
|
||||
value: [(function_expression) (arrow_function)])
|
||||
|
||||
(assignment_expression
|
||||
left: (identifier) @function
|
||||
right: [(function_expression) (arrow_function)])
|
||||
|
||||
; Function and method parameters
|
||||
;-------------------------------
|
||||
|
||||
; Arrow function parameters in the form `p => ...` are supported by both
|
||||
; javascript and typescript grammars without conflicts.
|
||||
(arrow_function
|
||||
parameter: (identifier) @variable.parameter)
|
||||
|
||||
; Function and method calls
|
||||
;--------------------------
|
||||
|
||||
(call_expression
|
||||
function: (identifier) @function)
|
||||
|
||||
(call_expression
|
||||
function: (member_expression
|
||||
property: (property_identifier) @function.method))
|
||||
(call_expression
|
||||
function: (member_expression
|
||||
property: (private_property_identifier) @function.method.private))
|
||||
|
||||
; Literals
|
||||
;---------
|
||||
|
||||
(this) @variable.builtin
|
||||
(super) @variable.builtin
|
||||
|
||||
[
|
||||
(null)
|
||||
(undefined)
|
||||
] @constant.builtin
|
||||
|
||||
[
|
||||
(true)
|
||||
(false)
|
||||
] @constant.builtin.boolean
|
||||
|
||||
(comment) @comment
|
||||
|
||||
[
|
||||
(string)
|
||||
(template_string)
|
||||
] @string
|
||||
|
||||
(escape_sequence) @constant.character.escape
|
||||
|
||||
(regex) @string.regexp
|
||||
(number) @constant.numeric.integer
|
||||
|
||||
; Special identifiers
|
||||
;--------------------
|
||||
|
||||
((identifier) @constructor
|
||||
(#match? @constructor "^[A-Z]"))
|
||||
|
||||
([
|
||||
(identifier)
|
||||
(shorthand_property_identifier)
|
||||
(shorthand_property_identifier_pattern)
|
||||
] @constant
|
||||
(#match? @constant "^[A-Z_][A-Z\\d_]+$"))
|
||||
|
||||
((identifier) @variable.builtin
|
||||
(#match? @variable.builtin "^(arguments|module|console|window|document)$")
|
||||
(#is-not? local))
|
||||
|
||||
(call_expression
|
||||
(identifier) @function.builtin
|
||||
(#any-of? @function.builtin
|
||||
"eval"
|
||||
"fetch"
|
||||
"isFinite"
|
||||
"isNaN"
|
||||
"parseFloat"
|
||||
"parseInt"
|
||||
"decodeURI"
|
||||
"decodeURIComponent"
|
||||
"encodeURI"
|
||||
"encodeURIComponent"
|
||||
"require"
|
||||
"alert"
|
||||
"prompt"
|
||||
"btoa"
|
||||
"atob"
|
||||
"confirm"
|
||||
"structuredClone"
|
||||
"setTimeout"
|
||||
"clearTimeout"
|
||||
"setInterval"
|
||||
"clearInterval"
|
||||
"queueMicrotask")
|
||||
(#is-not? local))
|
||||
100
queries/ecma/injections.scm
Normal file
100
queries/ecma/injections.scm
Normal file
@@ -0,0 +1,100 @@
|
||||
; Parse the contents of tagged template literals using
|
||||
; a language inferred from the tag.
|
||||
|
||||
(call_expression
|
||||
function: [
|
||||
(identifier) @injection.language
|
||||
(member_expression
|
||||
property: (property_identifier) @injection.language)
|
||||
]
|
||||
arguments: (template_string) @injection.content
|
||||
(#any-of? @injection.language "html" "css" "json" "sql" "js" "ts" "bash"))
|
||||
|
||||
; Parse the contents of $ template literals as shell commands
|
||||
|
||||
(call_expression
|
||||
function: [
|
||||
(identifier) @_template_function_name
|
||||
(member_expression
|
||||
property: (property_identifier) @_template_function_name)
|
||||
]
|
||||
arguments: (template_string) @injection.content
|
||||
(#eq? @_template_function_name "$")
|
||||
(#set! injection.language "bash"))
|
||||
|
||||
; GraphQL detection generally matches the rules provided by the 'GraphQL: Syntax Highlighting'
|
||||
; VSCode extension: https://github.com/graphql/graphiql/blob/8f25b38f4ab14dc99c046109f255fb283bccde52/packages/vscode-graphql-syntax/grammars/graphql.js.json
|
||||
|
||||
; Parse the contents of 'gql' and 'graphql' template literals and function calls
|
||||
(
|
||||
(call_expression
|
||||
function: (identifier) @_template_function_name
|
||||
arguments: [
|
||||
; Tagged template literal: NAME``
|
||||
(template_string (string_fragment) @injection.content)
|
||||
(
|
||||
arguments . [
|
||||
; Function call containing a string literal: NAME('')
|
||||
(string (string_fragment) @injection.content)
|
||||
; Function call containing a template literal: NAME(``)
|
||||
(template_string (string_fragment) @injection.content)
|
||||
]
|
||||
)
|
||||
]
|
||||
)
|
||||
(#any-of? @_template_function_name "gql" "graphql")
|
||||
(#set! injection.language "graphql")
|
||||
)
|
||||
|
||||
; Parse the contents of strings and tagged template literals that begin with a GraphQL comment '#graphql'
|
||||
(
|
||||
[
|
||||
(string (string_fragment) @injection.content)
|
||||
(template_string (string_fragment) @injection.content)
|
||||
]
|
||||
(#match? @injection.content "^\\s*#graphql")
|
||||
(#set! injection.language "graphql")
|
||||
)
|
||||
|
||||
; Parse the contents of strings and tagged template literals with leading ECMAScript comments '/* GraphQL */'
|
||||
(
|
||||
((comment) @_ecma_comment [
|
||||
(string (string_fragment) @injection.content)
|
||||
(template_string (string_fragment) @injection.content)
|
||||
])
|
||||
(#eq? @_ecma_comment "/* GraphQL */")
|
||||
(#set! injection.language "graphql")
|
||||
)
|
||||
|
||||
; Parse regex syntax within regex literals
|
||||
|
||||
((regex_pattern) @injection.content
|
||||
(#set! injection.language "regex"))
|
||||
|
||||
; Parse JSDoc annotations in multiline comments
|
||||
|
||||
((comment) @injection.content
|
||||
(#set! injection.language "jsdoc")
|
||||
(#match? @injection.content "^/\\*+"))
|
||||
|
||||
; Parse general tags in single line comments
|
||||
|
||||
((comment) @injection.content
|
||||
(#set! injection.language "comment")
|
||||
(#match? @injection.content "^//"))
|
||||
|
||||
; Match string literals passed to standard browser API methods that expects a
|
||||
; css selector as argument.
|
||||
; - https://developer.mozilla.org/en-US/docs/Web/API/Document/querySelector
|
||||
; - https://developer.mozilla.org/en-US/docs/Web/API/Document/querySelectorAll
|
||||
; - https://developer.mozilla.org/en-US/docs/Web/API/Element/closest
|
||||
; - https://developer.mozilla.org/en-US/docs/Web/API/Element/matches
|
||||
; e.g.
|
||||
; `const el = document.querySelector("div.user-panel.main input[name='login']");`
|
||||
(call_expression
|
||||
function: (member_expression
|
||||
object: (identifier) @_object
|
||||
property: (property_identifier) @_property (#any-of? @_property "querySelector" "querySelectorAll" "closest" "matches"))
|
||||
arguments: (arguments
|
||||
(string (string_fragment) @injection.content))
|
||||
(#set! injection.language "css"))
|
||||
26
queries/ecma/locals.scm
Normal file
26
queries/ecma/locals.scm
Normal file
@@ -0,0 +1,26 @@
|
||||
; Scopes
|
||||
;-------
|
||||
|
||||
[
|
||||
(statement_block)
|
||||
(arrow_function)
|
||||
(function_expression)
|
||||
(function_declaration)
|
||||
(method_definition)
|
||||
(for_statement)
|
||||
(for_in_statement)
|
||||
(catch_clause)
|
||||
(finally_clause)
|
||||
] @local.scope
|
||||
|
||||
; Definitions
|
||||
;------------
|
||||
|
||||
; i => ...
|
||||
(arrow_function
|
||||
parameter: (identifier) @local.definition.variable.parameter)
|
||||
|
||||
; References
|
||||
;------------
|
||||
|
||||
(identifier) @local.reference
|
||||
Reference in New Issue
Block a user