136be19533
Replace tree-sitter-highlight dep with tree-house crate from Helix editor. Add ropey dependency required by tree-house. Reorganize query files from Helix's runtime/queries/ for all 14 supported languages: - bash, c, css, go, html, javascript, json, markdown, nix, python, rust, toml, typescript, yaml - Include ecma, _javascript, _typescript base dirs for JS/TS inheritance - Copy highlights.scm, injections.scm, locals.scm where available This commit establishes the foundation; highlight.rs implementation will follow in subsequent commits.
39 lines
1001 B
Scheme
39 lines
1001 B
Scheme
((comment) @injection.content
|
|
(#set! injection.language "comment"))
|
|
|
|
(command
|
|
name: (command_name (word) @_command)
|
|
argument: (raw_string) @injection.content
|
|
(#match? @_command "^[gnm]?awk$")
|
|
(#set! injection.language "awk"))
|
|
|
|
((regex) @injection.content
|
|
(#set! injection.language "regex"))
|
|
|
|
(command
|
|
name: (command_name (word) @_command (#any-of? @_command "jq" "jaq"))
|
|
argument: [
|
|
(raw_string) @injection.content
|
|
(string (string_content) @injection.content)
|
|
]
|
|
(#set! injection.language "jq"))
|
|
|
|
(command
|
|
name: (command_name (word) @_command (#eq? @_command "alias"))
|
|
argument: (concatenation
|
|
(word)
|
|
[
|
|
(raw_string) @injection.content
|
|
(string (string_content) @injection.content)
|
|
])
|
|
(#set! injection.language "bash"))
|
|
|
|
(command
|
|
name: (command_name (word) @_command (#any-of? @_command "eval" "trap"))
|
|
.
|
|
argument: [
|
|
(raw_string) @injection.content
|
|
(string (string_content) @injection.content)
|
|
]
|
|
(#set! injection.language "bash"))
|